Вопрос: Как отключить всплывающую подсказку на вкладках


Есть ли способ отключить всплывающие подсказки на вкладках в Chrome?

Они могут раздражаться и отвлекаться всякий раз, когда указатель мыши находится на вкладке.


2
2017-10-06 16:38


Источник


Tooltips can get pretty annoying and distracting whenever the mouse pointer happens to be on a tab.   Это можно сказать о все всплывающие подсказки, но они (обычно) достаточно удобны, чтобы оправдать просто перемещение курсора в мертвое место. Может быть, программа или сценарий, чтобы автоматически это сделать? Хм ... - Synetech


Ответы:


Вы не можете отключить эти всплывающие подсказки в Chrome.

С помощью: http://productforums.google.com/forum/#!topic/chrome/ygoNhTB5K1Y https://groups.google.com/forum/#!topic/chromebook-central/gxAnZM-2tpM http://forums.mozillazine.org/viewtopic.php?f=7&t=1562905


3
2017-10-06 18:22





Я не мог получить идея программы перемещения курсора потому что ты сошел с ума, поэтому я бросил вместе.

Ниже приведен скрипт AutoHotkey (который может быть скомпилирован для автономного исполняемого файла, если это необходимо), который обнаруживает, когда курсор мыши некоторое время остается без изменений в верхней части окна Chrome, и если это так, перемещает его в нижний правый угол экран.

Он работает так, как ожидалось, и предотвращает всплытие всплывающих подсказок, но из-за ступенчатого выбора времени (запуск подпрограммы и обратного отсчета всплывающей подсказки) иногда всплывает всплывающая подсказка за секунду до перемещения курсора. Это можно уменьшить, уменьшив таймер ( tip переменная).

Я также подумываю об улучшении скрипта, манипулируя таймером вручную, вместо использования таймера AutoHotkey. Таким образом, он может рассчитывать с последнего момента, когда мышь была перемещена или нажата кнопка, а не только каждый Икс секунд.


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;   MoveIdleMouse.ahk
;
; Prevents tooltips from being annoying in Chrome by detecting
; when the mouse is idle while near the top of a Chrome window
; and then moving it to the bottom-right corner of the screen.
;
; https://superuser.com/questions/393738/
;
;   (cl) 2013- Synetech inc., Alec Soroudi
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

#SingleInstance force
#Persistent

; Read the tooltip delay from the registry (this is the amount of time the
; cursor has to hover over something in order to trigger the tooltip)
RegRead, tip, HKCU, Control Panel\Mouse, MouseHoverTime

; Divide it by two to accommodate staggared timing. Adjust as desired.
;tip:=tip/2

; Set specified subroutine to run every so often (before tooltip triggered)
SetTimer, CheckCursor, %tip%

; Get the current mouse cursor position to compare to during first interval
MouseGetPos, x1, y1
return

; This subroutine checks the current cursor position and moves if idle
CheckCursor:
  ; First check if the cursor is over a Chrome window; ignore if not
  IfWinNotActive, ahk_class Chrome_WidgetWin_0
    return

  ; Next, check if any buttons are pressed and ignore if so
  if (GetKeyState("LButton") or GetKeyState("RButton") or GetKeyState("MButton")
      or GetKeyState("XButton1") or GetKeyState("XButton2"))
    return

  ; Get the current mouse position and check if it is both unchanged, and
  ; near the top of Chrome (position is relative to window by default)
  MouseGetPos, x2, y2
  If (((x1 = x2) and (y1 = y2))  and  ((y2 >= 0) and (y2 <= 27)))
  {
    ; Move the cursor to the bottom-right corner of the screen immediately
    ; You can adjust destination position as desired
    MouseMove, A_ScreenWidth+3, A_ScreenHeight+3, 0
  }
  else {
    ; Update current cursor position to compare to during the next interval
    x1 := x2
    y1 := y2
  }
  return

3
2017-10-06 19:44



Мне жаль, что я не смог бы поддержать это дважды или принять его, но я запускаю Ubuntu. Мой плохой, должен был упомянуть об этом. - MarcusJuniusBrutus
Ах я вижу. К сожалению, в настоящее время нет AutoHotkey  для Linux, но IronAHK должен быть переносимым, так что это может стоить выстрела. Кроме того, для Linux есть другие инструменты для сценариев / автоматизации, поэтому, возможно, сценарий можно портировать на один из них. - Synetech